E-Maculation

Code: Select all

ruby -e "$(curl -fsSL https://raw.githubusercontent.com/Homebrew/install/master/install)"

Code: Select all

brew update

Code: Select all

brew doctor

Code: Select all

brew install qemu

Code: Select all

set gccPath to false
set brewPath to false
set qemuppcPath to false
set imagePath to false
set cdPath to ""
set resPath to (quoted form of (POSIX path of (path to me))) & "/Contents/Resources/"
set brewInstall to "ruby -e \"$(curl -fsSL https://raw.githubusercontent.com/Homebrew/install/master/install)\""
set brewUpdate to "/usr/local/bin/brew update"
set qemuInstall to "/usr/local/bin/brew install qemu"
set qemuUpgrade to "/usr/local/bin/brew upgrade qemu"

try
	set gccPath to do shell script "which gcc"
end try

if gccPath = false then
	display dialog "Sorry, XCode must be installed from the App Store along with the command-line tools to set this up." buttons {"OK"} default button 1 with icon stop giving up after 29
	return 0
else
	try
		set brewPath to do shell script "ls /usr/local/bin/brew"
	end try
	
	if brewPath = false then
		display dialog "HomeBrew is not installed.  Would you like to install it now?" buttons {"No thanks.", "Yes please!"} default button 2 with icon stop giving up after 29
		if the button returned of the result is "No thanks." then
			display dialog "Qemu setup terminated." buttons {"OK"} with icon caution giving up after 29
		else
			do shell script brewInstall
		end if
	end if
	
	try
		set qemuppcPath to do shell script "ls /usr/local/bin/qemu-system-ppc"
	end try
	
	if qemuppcPath = false then
		display dialog "QEMU PPC is not installed.  Would you like to install it now?" buttons {"No thanks.", "Yes please!"} default button 2 with icon stop giving up after 29
		if the button returned of the result is "No thanks." then
			display dialog "Qemu setup terminated." buttons {"OK"} with icon caution giving up after 29
		else
			do shell script brewUpdate
			do shell script qemuInstall
		end if
	end if
	
	do shell script brewUpdate
	try
		do shell script qemuUpgrade
	end try
	
	try
		set imagePath to do shell script "ls " & resPath & "HD.qcow2"
	end try
	
	if imagePath = false then
		display dialog "HDD image not found. What would you like to do?" buttons {"Create VM from raw image", "Create VM from Scratch"} default button "Create VM from Scratch" with icon note giving up after 29
		if the button returned of the result is "Create VM from Scratch" then
			set cdFile to choose file with prompt "Select OS X PPC 10.2-10.4 Install CD image:" of type {"CDR", "TOAST", "ISO", "IMG"}
			set cdFile to (quoted form of (POSIX path of cdFile))
			set cdPath to " -boot order=dc -cdrom " & cdFile
			do shell script "/usr/local/bin/qemu-img create -q -f qcow2 " & resPath & "HD.qcow2 6G"
		else if the button returned of the result is "Create VM from raw image" then
			--Select file(s)
			set imageFile to choose file with prompt "Select installed PearPC or other functional OS X 10.2-10.4 PPC HD image:" of type {"IMG", "DMG", "BOCHS", "QCOW2", "VPC", "VHDX", "NULL-AIO", "NBD", "BLKDEBUG", "SHEEPDOG", "BLKVERIFY", "QED", "NULL-CO", "VVFAT", "IMAGE", "VMDK", "RAW", "PARALLELS", "QUORUM", "VDI", "FTPS", "TFTP", "CLOOP", "QCOW", "FTP", "HTTPS", "HTTP", "FILE", "HOST_DEVICE"}
			
			--Convert file into posix path
			set imageFile to (quoted form of (POSIX path of imageFile))
			
			--Now we have our file path, so let's convert it
			do shell script "/usr/local/bin/qemu-img convert -O qcow2 " & imageFile & " " & resPath & "HD.qcow2"
		else
			return 0
		end if
	end if
	
	do shell script "/usr/local/bin/qemu-system-ppc -m 1024 -hda " & resPath & "HD.qcow2" & cdPath & " -prom-env 'boot-args=-v' -serial stdio"
	-- to do:
	-- look for config file
	-- no config: ask if running for first time
end if